[AdamSpeight2008]

Code Golf 2: Pyramid

Challenge: Write Function that take in an integer R ( greater than 0), and returns a string containing numerical pyramid of R rows.

Function Pyramid(ByVal R as Integer) As String
' Your Code goes here '
End Function

Example outputs
Pyramid of 2

3 1
  2

Pyramid of 3

6 3 1
  5 2
    4

Pyramid of 5

15 10  6  3  1
   14  9  5  2
      13  8  4
         12  7
            11

It is also required that all the number in the rows be right aligned in the columns.
So that means the follow output is wrong.

15 10 6 3 1
   14 9 5 2
      13 8 4
         12 7
            11

Restrictions
The code must be compiled with the following options turned on.

Option Strict On
Option Infer On

When submitting the .net framework version it target should also included.

Scoring
Is the number of count of non white space characters minus the 6 for implicit return statement.

This post has been edited by AdamSpeight2008: 11 February 2011 - 11:00 AM

[AdamSpeight2008]

This hole has seemed to scared away a lot of golfers, so I guess its a Par 6 hole.

So here's my opening attempt.
Score: 282

Spoiler

  Public Function Pyramid(ByVal R As Integer) As String
    Dim g As New List(Of String)
    Dim P = (R * R + R) / 2
    Dim T = (P - R + 1)
    Dim w = P.ToString.Length + 1
    Dim u = 2
    Dim s = ""
    While P >= T
      Dim q = P
      Dim d = R
      s &= q.ToString.PadLeft(w, " "c)
      While d >= u
        q -= d
        s &= q.ToString.PadLeft(w, " "c)
        d -= 1
      End While
      g.Add(s)
      s = ""
      P -= 1
      u += 1
    End While
    For Each x In g
      s &= x.PadLeft(g(0).Length, " "c) & ControlChars.NewLine
    Next
    Return s
  End Function

[T3hC13h]

I had to fall back on some old methods from the VisualBasic namespace to bum the count down.

Score: 196

Spoiler

    Function Pyramid(ByVal R As Integer) As String
        Dim s(R - 1) As Stack
        Dim n
        For i = 0 To R - 1
            s(i) = New Stack
            s(i).Push(n)
            n += 1
            For j = i - 1 To 0 Step -1
                s(j).Push(n)
                n += 1
            Next
        Next
        Dim t
        For Each z In s
            Dim w = ""
            For Each j In z
                w &= RSet(Str(j), Len(n))
            Next
            t &= RSet(w, R * Len(n)) & vbNewLine
        Next
        Return t
    End Function

This post has been edited by T3hC13h: 15 February 2011 - 02:14 PM

[lordofduct]

180

Spoiler

    Function Pyramid(ByVal R As Integer) As String
        Dim z = ""
        Dim s = ""
        Dim m = (R * R + R) / 2
        Dim p = CInt(Math.Ceiling(Math.Log10(m))) + 1
        Dim l = p * R
        Dim t = m

        For i = 1 To R
            t = m
            s = ""
            For j = R To i Step -1
                s &= Str(t).PadLeft(p, " "c)
                t -= j
            Next
            z &= s.PadLeft(l, " "c) & vbCrLf
            m -= 1
        Next

        Return z
    End Function

[AdamSpeight2008]

lordofduct Sweet code.

[lordofduct]

Thanks

I was a little late to the game, but I only saw the post today. I like these a lot, I hope you and Curtis (over in C#) do more of them.


I do also do the ones over at Euler Project, tons of fun.



Oh and 171, forgot about the 'Int' method, that's shorter than Math.Ceiling and Math.Floor (to bad the CInt cast rounds instead of floors)

Spoiler

    Function Pyramid(ByVal R As Integer) As String
        Dim z = ""
        Dim s = ""
        Dim m = (R * R + R) / 2
        Dim p = CInt(Int(Math.Log10(m))) + 2
        Dim l = p * R
        Dim t = m

        For i = 1 To R
            t = m
            s = ""
            For j = R To i Step -1
                s &= Str(t).PadLeft(p, " "c)
                t -= j
            Next
            z &= s.PadLeft(l, " "c) & vbCrLf
            m -= 1
        Next

        Return z
    End Function

This post has been edited by lordofduct: 12 April 2011 - 02:50 PM

[AdamSpeight2008]

lordofduct a few tweaks of yours and it now 159

Spoiler

  Function Pyramid(ByVal R As Integer) As String
    Dim z = ""
    Dim m = (R * R + R) \ 2
    Dim p = CInt(Math.Log10(m) + 2)


    For i = 1 To R
      Dim t = m
      Dim s = ""
      For j = R To i Step -1
        s &= Str(t).PadLeft(p, " "c)
        t -= j
      Next
      z &= s.PadLeft(p * R, " "c) & vbCrLf
      m -= 1
    Next

    Return z
  End Function

151

Spoiler

  Function Pyramid(ByVal R As Integer) As String
    Dim z = ""
    Dim m = (R * R + R) \ 2
    Dim p = CInt(Math.Log10(m) + 2)


    For i = 1 To R
      Dim t = m
      Dim s = ""
      For j = R To i Step -1
        s &= Str(t).PadLeft(p)
        t -= j
      Next
      z &= s.PadLeft(p * R) & vbCrLf
      m -= 1
    Next

    Return z
  End Function

This post has been edited by AdamSpeight2008: 12 April 2011 - 03:16 PM

[lordofduct]

CInt(...) rounds though, and the Log10 needs to be floored.

[AdamSpeight2008]

What size of pyramid would the effect of rounded vs floored be evident?

[lordofduct]

3 will get a 3 space padding when it should get 2 [ log(6) + 2 -> 3 ]

8 through 13 will get a 4 space padding when it should only get 3.

The next won't be until 25 with 5 spaces when there should be 4 and will last until 44 [when: 10^2.5 < (R^2 + R)/2 < 10^3]

It will always occur when Log10(R^2 + R) % 1 > 0.5



we still get 150 with:

Spoiler

        Dim z = ""
        Dim m = (R * R + R) \ 2
        Dim p = CInt(Int(Math.Log10(m)) + 2)

        For i = 1 To R
            Dim t = m
            Dim s = ""
            For j = R To i Step -1
                s &= Str(t).PadLeft(p)
                t -= j
            Next
            z &= s.PadLeft(p * R) & vbCrLf
            m -= 1
        Next

        Return z

(your 151 score before should have been 145, you said -6 for the implicit Return... that or this one is 156)

This post has been edited by lordofduct: 13 April 2011 - 08:26 AM

[Curtis Rutland]

I can't believe I missed this one. Too bad. Here's one in C#. Not great, think it's 242 if you're not counting any whitespace:

Spoiler

static string Pyramid(int r) {
    var m = new string[r, r];
    int i, j, v, w, x, y;
    for (y = r - 1, i = 1, w = 0; y >= 0; y--, i++)
        for (x = 0, j = i, v = w += i; x < r - i + 1; x++, v += j++)
            m[x, y] = v.ToString();
    string s = "";
    for (i = 0; i < r; i++, s += "\n")
        for (j = 0; j < r; j++)
            s += (m[i, j] ?? "").PadLeft(m[0, 0].Length + 1);
    return s;
}

I did this without looking at other solutions. I'm not great at math, so I brute-forced it somewhat.

[T3hC13h]

A slight improvement on the last few works of lordofduct and AdamSpeight2008

Count: 126

Spoiler

        
Dim z = ""
Dim m = (R * R + R) \ 2
Dim p = Len(Str(m))
For i = 1 To R
    Dim t = m
    z &= Space(p * (i - 1))
    For j = R To i Step -1
        z &= RSet(Str(t), p)
        t -= j
    Next
    z &= vbCrLf
    m -= 1
Next

This post has been edited by T3hC13h: 05 May 2011 - 11:02 AM