[AdamSpeight2008]

Challenge: Conway's Game of Life

Let's start off the life of the new Challenges forum, with you implement life itself (well at least Conway's version of it).

Challenge

• Create UI-agnostic class that is capable of simulating Conway's Game of Life.
  
• Create a UI that displays the current state of the game.

---

Life Rules

• Any cell with fewer than 2 neighbors dies (of loneliness)
  
• Any cell with 2 or 3 neighbors, survives into the next generation.
  
• Any cell with more than 3 neighbor dies (of over crowding)
  
• Any dead cell with exactly three neighbors, becomes alive (as if by reproduction)

The World
The world on which these cells live is a Torus.
So the top and a bottom edges are connected and the left and right edges are connected.

Requirements

- Publicly you can only create instance of them via one of, the following two factory methods.
CreateNew

Dim cwi = ConwayGame.CreateNew( Width:= 320, Height:= 240 )

CreateRandom

Dim cwi = ConwayGame.CreateNew( Width:= 320, Height:= 240, AliveCells:= 25000 )

Must be capable of generating at bitmap of the current state of the Conway Game, via the following shared function.

Dim bmp = ConwayGame.ToBitmap( ThisInstanceOfConwayGame )

The instance must have a function that returns to number of Alive Cells.
eg.

Dim acc = ThisInstanceOfConwayGame.AliveCellCount()

---

Entrants

• Frameworks required.
  
• vb.net submissions are preferred.
  
• SourceCode must be in spoilered code tags.
  
  Spoiler

  
  If you don't want to reveal your code, then don't submit a submission.
  
• If you like you can include a Zip-File of the project / executable.

This post has been edited by AdamSpeight2008: 01 January 2012 - 11:36 PM

[cfoley]

The first time I saw Conway's game of life was on the cassette supplied with the 48K Spectrum. I'll have a submission soon.

I like your challenges. Keep up the good work!

One question. Do cells have eight neighbours or four?

[AdamSpeight2008]

Every cell interacts with its eight neighbours, which are the cells that are horizontally, vertically, or diagonally adjacent.

[cfoley]

Here is my first attempt. I'm going to have a shot at refactoring it to be more OO. I think that would make a few optimisations quite easy:

Spoiler

Public Class GameOfLife
    Private Const defaultLivePercentage = 10
    Private cells(,) As Boolean
    Private width, height, aliveCells As Integer
    Private bitmap As Bitmap

    Public Sub New(ByVal Width As Integer, ByVal Height As Integer)
        Me.New(Width, Height, (Width * Height * defaultLivePercentage / 100))
    End Sub

    Public Sub New(ByVal Width As Integer, ByVal Height As Integer, ByVal AliveCells As Integer)
        Me.width = Width
        Me.height = Height
        ReDim cells(Width - 1, Height - 1)
        Dim cellCount = Width * Height
        Me.aliveCells = Math.Min(AliveCells, cellCount)
        Bitmap = New Bitmap(Width, Height)
        If (2 * AliveCells < cellCount) Then
            populateCells(AliveCellCount())
        Else
            populateCells(cellCount - AliveCellCount())
            For x = 0 To Width - 1
                For y = 0 To Height - 1
                    cells(x, y) = Not cells(x, y)
                Next
            Next
        End If
        For x = 0 To Width - 1
            For y = 0 To Height - 1
                If cells(x, y) Then bitmap.SetPixel(x, y, Color.Black)
            Next
        Next

    End Sub

    Private Sub populateCells(ByVal denizens As Integer)
        For i = 1 To denizens
            Dim x, y As Integer
            Dim rand = New Random()
            Do
                x = rand.Next(width)
                y = rand.Next(height)
            Loop While (cells(x, y))
            cells(x, y) = True
        Next
    End Sub

    Public Shared Function ToBitmap(ByVal game As GameOfLife) As Bitmap
        Return game.toBitmap
    End Function

    Public Function toBitmap() As Bitmap
        Return bitmap
    End Function

    Public Function AliveCellCount() As Integer
        Return aliveCells
    End Function

    Public Sub nextGeneation()
        Dim children(width - 1, height - 1) As Boolean
        For x = 0 To width - 1
            For y = 0 To height - 1
                children(x, y) = isNextGenerationAlive(x, y)
                If (children(x, y) <> cells(x, y)) Then
                    If children(x, y) Then
                        bitmap.SetPixel(x, y, Color.Black)
                        aliveCells += 1
                    Else
                        bitmap.SetPixel(x, y, Color.Yellow)
                        aliveCells -= 1
                    End If
                End If

            Next
        Next
        cells = children
    End Sub

    Private Function aliveNeighbours(ByVal x As Integer, ByVal y As Integer) As Integer
        Dim result = 0
        For xx = x - 1 To x + 1
            For yy = y - 1 To y + 1
                If cells((xx + width) Mod width, (yy + height) Mod height) Then result += 1
            Next
        Next
        If cells(x, y) Then result -= 1
        Return result
    End Function

    Private Function isNextGenerationAlive(ByVal x, ByVal y)
        Dim neighbours = aliveNeighbours(x, y)
        Return neighbours = 3 Or (cells(x, y) And neighbours = 2)
    End Function


End Class

And the GUI:

Spoiler

Public Class GameGUI

    Private game As GameOfLife
    Private generations As Integer

    Public Sub New()

        ' This call is required by the designer.
        InitializeComponent()

        ' Add any initialization after the InitializeComponent() call.

    End Sub

    Protected Overrides Sub Finalize()
        MyBase.Finalize()
    End Sub

    Private Sub GameGUI_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    End Sub

    Private Sub Start_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Start.Click
        generations = 0
        game = New GameOfLife(GameView.Width, GameView.Height)
        refreshDisplay()
        GenerationTimer.Start()
    End Sub

    Private Sub StopButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles StopButton.Click
        GenerationTimer.Stop()
    End Sub

    Private Sub GenerationTimer_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles GenerationTimer.Tick
        game.nextGeneation()
        refreshDisplay()
    End Sub

    Private Sub refreshDisplay()
        GameView.Image = game.toBitmap
        generations += 1
        GenerationCount.Text = "Generations: " & generations
        aliveCells.Text = "Alive Cells: " & game.AliveCellCount
    End Sub
End Class

[cfoley]

Tried my OO version. It failed miserably.

My thinking was that I could have a Cell class. Then instead of scanning the entire torus, I could work off a set of alive cells, looking at them to see if they died and their neighbours to see if they came to life. Turns out that too much of the board is in use for this to offset all those method calls, and especially the initial object creation.

[AdamSpeight2008]

cfoley you may want to re-examine to requirements, factory-method creating of instances.
Any how. Nice to see somebody taking a interest.

What rate you getting? Generations Drawn/Sec ?


I may need to sit and examine this bit, just to see if the obeys the "life rules", plus a return type would help.

Private Function isNextGenerationAlive(ByVal x, ByVal y)
  Dim neighbours = aliveNeighbours(x, y)
  Return neighbours = 3 Or (cells(x, y) And neighbours = 2)
End Function

P.S. You don't know anyone with a lots of CPU cores going spare. As mine is maxing both cores on my desktop, I may have to awoken the beast (old rack server).

This post has been edited by AdamSpeight2008: 03 January 2012 - 01:17 PM

[cfoley]

Oops my mistake. I've put in the factory methods. Here is how I got to my life rules logic.

Spoiler

Taking your four rules, this is pretty straightforward:

    Private Function isNextGenerationAlive(ByVal x, ByVal y) As Boolean
        Dim neighbours = aliveNeighbours(x, y)
        ' if the cell is alive
        If (cells(x, y)) Then
            ' stays alive only when there are 2 or 3 neighbors
            Return neighbours = 2 Or neighbours = 3
        Else
            ' Dead cells only become alive if they have 3 live neighbours
            Return neighbours = 3
        End If
    End Function

You can see that if there are 3 live neighbours, the result is always true. Refactor to this:

    Private Function isNextGenerationAlive(ByVal x, ByVal y) As Boolean
        Dim neighbours = aliveNeighbours(x, y)
        If neighbours = 3 Then Return True
        If (cells(x, y)) Then
            ' 3 is already dealt with
            Return neighbours = 2
        Else
            ' This dead cell must stay dead
            Return False
        End If
    End Function

Reshuffle the if statement:

    Private Function isNextGenerationAlive(ByVal x, ByVal y) As Boolean
        Dim neighbours = aliveNeighbours(x, y)
        If neighbours = 3 Then Return True
        If (cells(x, y) And neighbours = 2) Then Return True
        Return False
    End Function

Now group the trues together:

    Private Function isNextGenerationAlive(ByVal x, ByVal y) As Boolean
        Dim neighbours = aliveNeighbours(x, y)
        If neighbours = 3 Or (cells(x, y) And neighbours = 2) Then Return True
        Return False
    End Function

Finally, just return the answer to the boolean expression:

    Private Function isNextGenerationAlive(ByVal x, ByVal y) As Boolean
        Dim neighbours = aliveNeighbours(x, y)
        return neighbours = 3 Or (cells(x, y) And neighbours = 2) 
    End Function

And here are my amended classes:

Spoiler

Public Class GameOfLife
    Private Const defaultLivePercentage = 10
    Private cells(,) As Boolean
    Private width, height, aliveCells As Integer
    Private bitmap As Bitmap

    Public Shared Function createNew(ByVal Width As Integer, ByVal Height As Integer) As GameOfLife
        Return New GameOfLife(Width, Height, (Width * Height * defaultLivePercentage / 100))
    End Function

    Public Shared Function createNew(ByVal Width As Integer, ByVal Height As Integer, ByVal AliveCells As Integer) As GameOfLife
        Return New GameOfLife(Width, Height, AliveCells)
    End Function

    Private Sub New(ByVal Width As Integer, ByVal Height As Integer, ByVal AliveCells As Integer)
        Me.width = Width
        Me.height = Height
        ReDim cells(Width - 1, Height - 1)
        Dim cellCount = Width * Height
        Me.aliveCells = Math.Min(AliveCells, cellCount)
        bitmap = New Bitmap(Width, Height)
        If (2 * AliveCells < cellCount) Then
            populateCells(AliveCellCount())
        Else
            populateCells(cellCount - AliveCellCount())
            For x = 0 To Width - 1
                For y = 0 To Height - 1
                    cells(x, y) = Not cells(x, y)
                Next
            Next
        End If
        For x = 0 To Width - 1
            For y = 0 To Height - 1
                If cells(x, y) Then bitmap.SetPixel(x, y, Color.Black)
            Next
        Next

    End Sub

    Private Sub populateCells(ByVal denizens As Integer)
        For i = 1 To denizens
            Dim x, y As Integer
            Dim rand = New Random()
            Do
                x = rand.Next(width)
                y = rand.Next(height)
            Loop While (cells(x, y))
            cells(x, y) = True
        Next
    End Sub

    Public Shared Function ToBitmap(ByVal game As GameOfLife) As Bitmap
        Return game.toBitmap
    End Function

    Public Function toBitmap() As Bitmap
        Return bitmap
    End Function

    Public Function AliveCellCount() As Integer
        Return aliveCells
    End Function

    Public Sub nextGeneation()
        Dim children(width - 1, height - 1) As Boolean
        For x = 0 To width - 1
            For y = 0 To height - 1
                children(x, y) = isNextGenerationAlive(x, y)
                If (children(x, y) <> cells(x, y)) Then
                    If children(x, y) Then
                        bitmap.SetPixel(x, y, Color.Black)
                        aliveCells += 1
                    Else
                        bitmap.SetPixel(x, y, Color.Yellow)
                        aliveCells -= 1
                    End If
                End If

            Next
        Next
        cells = children
    End Sub

    Private Function aliveNeighbours(ByVal x As Integer, ByVal y As Integer) As Integer
        Dim result = 0
        For xx = x - 1 To x + 1
            For yy = y - 1 To y + 1
                If cells((xx + width) Mod width, (yy + height) Mod height) Then result += 1
            Next
        Next
        If cells(x, y) Then result -= 1
        Return result
    End Function

    Private Function isNextGenerationAlive(ByVal x, ByVal y) As Boolean
        Dim neighbours = aliveNeighbours(x, y)
        Return neighbours = 3 Or (cells(x, y) And neighbours = 2)
    End Function

End Class

As far as performance goes, the refresh rate is controlled by a GUI timer. If I set the delay to 1 ms, and the image size to 320x240 and 25000 live cells, I get 836 frames in 1 minute (timed manually with a stopwatch). That's Just under 14 frames per second. However, the first couple of frames are much slower than the rest due to the number of cells dying (and therefore pixel editing in the image). CPU is at 25% with no multithreading. i.e. one core is maxed out.

Spoiler

Public Class GameGUI

    Private game As GameOfLife
    Private generations As Integer

    Public Sub New()

        ' This call is required by the designer.
        InitializeComponent()

        ' Add any initialization after the InitializeComponent() call.
        generations = 0
        game = GameOfLife.createNew(GameView.Width, GameView.Height, 25000)
    End Sub

    Protected Overrides Sub Finalize()
        MyBase.Finalize()
    End Sub

    Private Sub GameGUI_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    End Sub

    Private Sub Start_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Start.Click
        refreshDisplay()
        GenerationTimer.Start()
    End Sub

    Private Sub StopButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles StopButton.Click
        GenerationTimer.Stop()
        generations = 0
        game = GameOfLife.createNew(GameView.Width, GameView.Height, 25000)
    End Sub

    Private Sub GenerationTimer_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles GenerationTimer.Tick
        game.nextGeneation()
        refreshDisplay()
    End Sub

    Private Sub refreshDisplay()
        GameView.Image = game.toBitmap
        generations += 1
        GenerationCount.Text = "Generations: " & generations
        aliveCells.Text = "Alive Cells: " & game.AliveCellCount
    End Sub
End Class

This post has been edited by cfoley: 03 January 2012 - 06:03 PM

[maffelu]

Was this only in VB.NET? Because I made one using jQuery, it's easier having it on the web

http://demo.morkalork.com/game/CGoL/

[AdamSpeight2008]

maffelu: vb.net submissions are preferred.
Allows other languages but since this in vb.net I would like it if they were predominantly vb.net.

[AdamSpeight2008]

You can see me entry posted in my blog post. (As the code is a bit long)

On a 320 x 240 world with 25000 seeds, it does (on my machine) ~40 generations a second.

Note: There no point setting the timer below 25ms as windows and .net can time accurately.

This post has been edited by AdamSpeight2008: 04 January 2012 - 06:35 AM

[piman314]

Here's my entry. Runs on Client Profile 4.0.
Runs at ~50 generations/second on my machine once it gets running.
It is a bit simplistic, but it works. The title text is "gen/sec alivecount".

ConwayGame

Spoiler

Imports System.Drawing.Imaging
Imports System.Runtime.InteropServices
Imports System.Threading.Tasks
Public Class ConwayGame

#Region "Instance Variables"
    Private width As Integer
    Private height As Integer
    Private alive As Integer
    Private pixels() As Integer
    Private bmp As Bitmap

    Private Const aliveVal As Integer = &HFF000000
    Private Const deadVal As Integer = &HFFFFFFFF
#End Region

    Public Shared Function CreateNew(ByVal Width As Integer, ByVal height As Integer, Optional ByVal AliveCells As Integer = 0)
        If AliveCells = 0 Then
            AliveCells = Width * height / 20
        End If
        Return New ConwayGame(Width, height, AliveCells)
    End Function

    Public Shared Function ToBitmap(ByVal cwi As ConwayGame) As Bitmap
        Return cwi.bmp
    End Function

    Private Sub New(ByVal width As Integer, ByVal height As Integer, ByVal initlive As Integer)
        Me.height = height
        Me.width = width
        ReDim pixels(width * height)

        Dim rand As New Random()
        While initlive > 0
            Dim index As Integer = 0
            Do
                index = rand.Next(0, width * height)
            Loop While pixels(index) = aliveVal
            pixels(index) = aliveVal
            alive += 1
            initlive -= 1
        End While
        bmp = New Bitmap(width, height)
    End Sub

    Private Function ToIndex(ByVal x As Integer, ByVal y As Integer) As Integer
        If x < 0 Then
            x += width
        ElseIf x >= width Then
            x -= width
        End If
        If y < 0 Then
            y += height
        ElseIf y >= height Then
            y -= height
        End If
        Return y * width + x
    End Function

    Public Sub Generation()
        Dim newpixels(width * height) As Integer
        Dim newalive As Integer = 0
        Parallel.For(0, width, Sub(x As Integer)
                                   Parallel.For(0, height, Sub(y As Integer)
                                                               Dim index As Integer = ToIndex(x, y)
                                                               If AliveNext(x, y) Then
                                                                   newpixels(index) = aliveVal
                                                                   newalive += 1
                                                               Else
                                                                   newpixels(index) = deadVal
                                                               End If
                                                           End Sub)
                               End Sub)
        pixels = newpixels
        alive = newalive
        pushBitmap()
    End Sub

    Public Function AliveCellCount() As Integer
        Return alive
    End Function

    Private Function AliveNext(ByVal x As Integer, ByVal y As Integer) As Boolean
        Dim a As Integer = 0
        If pixels(ToIndex(x - 1, y - 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x, y - 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x + 1, y - 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x - 1, y)) = aliveVal Then a += 1
        If pixels(ToIndex(x + 1, y)) = aliveVal Then a += 1
        If pixels(ToIndex(x - 1, y + 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x, y + 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x + 1, y + 1)) = aliveVal Then a += 1
        Return a = 2 Or a = 3
    End Function

    Private Sub pushBitmap()
        Dim data As BitmapData = bmp.LockBits(New Rectangle(Point.Empty, bmp.Size), ImageLockMode.ReadWrite, PixelFormat.Format32bppArgb)
        Marshal.Copy(pixels, 0, data.Scan0, width * height)
        bmp.UnlockBits(data)
    End Sub

End Class

GUI

Spoiler

Imports System.Threading
Public Class frmView
    Inherits Form

    Dim t As Thread

    Private Sub frmView_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        t = New Thread(AddressOf Generate)
        t.Start()
        frmView.CheckForIllegalCrossThreadCalls = False
    End Sub

    Private Sub Generate()
        Try
            Dim cwi As ConwayGame = ConwayGame.CreateNew(320, 240, 25000)
            Dim generations As Integer = 0
            Dim stopwatch As Stopwatch = New Stopwatch()
            Dim times(30) As Integer
            Dim index As Integer = 0
            Dim timesum As Integer = 0
            stopwatch.Start()
            While Thread.CurrentThread.ThreadState <> ThreadState.AbortRequested
                cwi.Generation()
                generations += 1
                picConway.Image = ConwayGame.ToBitmap(cwi)
                timesum -= times(index)
                times(index) = stopwatch.ElapsedMilliseconds
                timesum += times(index)
                Me.Text = String.Format("{0:F2} {1:D}", 30 / (timesum / 1000D), cwi.AliveCellCount())
                index += 1
                If index = 30 Then index = 0
                stopwatch.Restart()
            End While
        Catch ex As Exception
            Console.WriteLine(ex)
        End Try
    End Sub

    Private Sub frmView_FormClosing(ByVal sender As System.Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles MyBase.FormClosing
        t.Abort()
    End Sub

#Region "Designer Code"

    Public Sub New()
        InitializeComponent()
    End Sub

    'Form overrides dispose to clean up the component list.
    <System.Diagnostics.DebuggerNonUserCode()> _
    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub

    'Required by the Windows Form Designer
    Private components As System.ComponentModel.IContainer

    'NOTE: The following procedure is required by the Windows Form Designer
    'It can be modified using the Windows Form Designer.  
    'Do not modify it using the code editor.
    <System.Diagnostics.DebuggerStepThrough()> _
    Private Sub InitializeComponent()
        Me.picConway = New System.Windows.Forms.PictureBox()
        CType(Me.picConway, System.ComponentModel.ISupportInitialize).BeginInit()
        Me.SuspendLayout()
        '
        'picConway
        '
        Me.picConway.Location = New System.Drawing.Point(0, 0)
        Me.picConway.Name = "picConway"
        Me.picConway.Size = New System.Drawing.Size(320, 240)
        Me.picConway.TabIndex = 0
        Me.picConway.TabStop = False
        '
        'frmView
        '
        Me.AutoScaleDimensions = New System.Drawing.SizeF(6.0!, 13.0!)
        Me.AutoScaleMode = System.Windows.Forms.AutoScaleMode.Font
        Me.ClientSize = New System.Drawing.Size(320, 240)
        Me.Controls.Add(Me.picConway)
        Me.Name = "frmView"
        Me.Text = "Conway's Game of Life"
        CType(Me.picConway, System.ComponentModel.ISupportInitialize).EndInit()
        Me.ResumeLayout(False)

    End Sub
    Friend WithEvents picConway As System.Windows.Forms.PictureBox
#End Region
End Class

This post has been edited by piman314: 04 January 2012 - 10:47 AM

[AdamSpeight2008]

Just look at your code, not tried running it yet.
piman314: First think I spotted, in your code.

Quote

frmView.CheckForIllegalCrossThreadCalls = False

Is asking for trouble, and your ignoring the issue.

The I spotted that your incrementing a shared variable on different tasks, non atomically. Increasing the odds of it producing the wrong value. When you count living cells.

Thirdly your way of calculating the average time seems wrong to me. Until at least 30 generation have to occur before you can average over 30. So first 29 generation have incorrect value for the rate,

This post has been edited by AdamSpeight2008: 04 January 2012 - 03:17 PM

[AdamSpeight2008]

piman314: I've run it an it is using the wrong rules.

[piman314]

I was hoping you wouldn't call me out on my bad practice

-I fixed the form thread issues by making the window text and image setting invoked.
-The numerator in the generations/sec counter now counts up to 30 instead of having an inaccurate value for the first 29 generations.
-Fixed the alive counter by using Interlocked.Increment and switched it to a for loop inside a Parallel.For (which seems to be faster than nesting Parallel.For on my machine)
-Fixed the rule error in AliveNext

I think that's everything.

ConwayGame

Spoiler

Imports System.Drawing.Imaging
Imports System.Runtime.InteropServices
Imports System.Threading.Tasks
Imports System.Threading
Public Class ConwayGame

#Region "Instance Variables"
    Private width As Integer
    Private height As Integer
    Private alive As Integer
    Private pixels() As Integer
    Private bmp As Bitmap

    Private Const aliveVal As Integer = &HFF000000
    Private Const deadVal As Integer = &HFFFFFFFF
#End Region

    Public Shared Function CreateNew(ByVal Width As Integer, ByVal height As Integer, Optional ByVal AliveCells As Integer = 0)
        If AliveCells = 0 Then
            AliveCells = Width * height / 20
        End If
        Return New ConwayGame(Width, height, AliveCells)
    End Function

    Public Shared Function ToBitmap(ByVal cwi As ConwayGame) As Bitmap
        cwi.pushBitmap()
        Return cwi.bmp
    End Function

    Private Sub New(ByVal width As Integer, ByVal height As Integer, ByVal initlive As Integer)
        Me.height = height
        Me.width = width
        ReDim pixels(width * height)

        Dim rand As New Random()
        While initlive > 0
            Dim index As Integer = 0
            Do
                index = rand.Next(0, width * height)
            Loop While pixels(index) = aliveVal
            pixels(index) = aliveVal
            alive += 1
            initlive -= 1
        End While
        bmp = New Bitmap(width, height)
    End Sub

    Private Function ToIndex(ByVal x As Integer, ByVal y As Integer) As Integer
        If x < 0 Then
            x += width
        ElseIf x >= width Then
            x -= width
        End If
        If y < 0 Then
            y += height
        ElseIf y >= height Then
            y -= height
        End If
        Return y * width + x
    End Function

    Public Sub Generation()
        Dim newpixels(width * height) As Integer
        Dim newalive As Integer = 0
        Parallel.For(0, width, Sub(x As Integer)
                                   For y As Integer = 0 To height - 1
                                       Dim index As Integer = ToIndex(x, y)
                                       If AliveNext(x, y) Then
                                           newpixels(index) = aliveVal
                                           Interlocked.Increment(newalive)
                                       Else
                                           newpixels(index) = deadVal
                                       End If
                                   Next
                               End Sub)
        pixels = newpixels
        alive = newalive
    End Sub

    Public Function AliveCellCount() As Integer
        Return alive
    End Function

    Private Function AliveNext(ByVal x As Integer, ByVal y As Integer) As Boolean
        Dim a As Integer = 0
        If pixels(ToIndex(x - 1, y - 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x, y - 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x + 1, y - 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x - 1, y)) = aliveVal Then a += 1
        If pixels(ToIndex(x + 1, y)) = aliveVal Then a += 1
        If pixels(ToIndex(x - 1, y + 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x, y + 1)) = aliveVal Then a += 1
        If pixels(ToIndex(x + 1, y + 1)) = aliveVal Then a += 1
        Return (a = 2 And pixels(ToIndex(x, y))) Or a = 3
    End Function

    Private Sub pushBitmap()
        Dim data As BitmapData = bmp.LockBits(New Rectangle(Point.Empty, bmp.Size), ImageLockMode.ReadWrite, PixelFormat.Format32bppArgb)
        Marshal.Copy(pixels, 0, data.Scan0, width * height)
        bmp.UnlockBits(data)
    End Sub

End Class

GUI

Spoiler

Imports System.Threading
Public Class frmView
    Inherits Form

    Dim t As Thread

    Private Sub frmView_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        t = New Thread(AddressOf Generate)
        t.Start()
    End Sub

    Private Sub Generate()
        Try
            Dim cwi As ConwayGame = ConwayGame.CreateNew(320, 240, 25000)
            Dim generations As Integer = 0
            Dim stopwatch As Stopwatch = New Stopwatch()
            Dim times(30) As Integer
            Dim index As Integer = 0
            Dim timesum As Integer = 0
            Dim frames As Integer = 0
            stopwatch.Start()
            While Thread.CurrentThread.ThreadState <> ThreadState.AbortRequested
                cwi.Generation()
                generations += 1
                timesum -= times(index)
                times(index) = stopwatch.ElapsedMilliseconds
                timesum += times(index)
                frames = If(frames < 30, frames + 1, 30)
                Me.Invoke(New Action(Of String)(AddressOf setText), String.Format("{0:F2} {1:D}", frames / (timesum / 1000D), cwi.AliveCellCount()))
                Me.Invoke(New Action(Of ConwayGame)(AddressOf pushBitmap), cwi)
                index += 1
                If index = 30 Then index = 0
                stopwatch.Restart()
            End While
        Catch ex As Exception
            Console.WriteLine(ex)
        End Try
    End Sub

    Private Sub setText(ByVal str As String)
        Me.Text = str
    End Sub

    Private Sub pushBitmap(ByVal cwi As ConwayGame)
        picConway.Image = ConwayGame.ToBitmap(cwi)
    End Sub

    Private Sub frmView_FormClosing(ByVal sender As System.Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles MyBase.FormClosing
        t.Abort()
    End Sub

#Region "Designer Code"

    Public Sub New()
        InitializeComponent()
    End Sub

    'Form overrides dispose to clean up the component list.
    <System.Diagnostics.DebuggerNonUserCode()> _
    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub

    'Required by the Windows Form Designer
    Private components As System.ComponentModel.IContainer

    'NOTE: The following procedure is required by the Windows Form Designer
    'It can be modified using the Windows Form Designer.  
    'Do not modify it using the code editor.
    <System.Diagnostics.DebuggerStepThrough()> _
    Private Sub InitializeComponent()
        Me.picConway = New System.Windows.Forms.PictureBox()
        CType(Me.picConway, System.ComponentModel.ISupportInitialize).BeginInit()
        Me.SuspendLayout()
        '
        'picConway
        '
        Me.picConway.Location = New System.Drawing.Point(0, 0)
        Me.picConway.Name = "picConway"
        Me.picConway.Size = New System.Drawing.Size(320, 240)
        Me.picConway.TabIndex = 0
        Me.picConway.TabStop = False
        '
        'frmView
        '
        Me.AutoScaleDimensions = New System.Drawing.SizeF(6.0!, 13.0!)
        Me.AutoScaleMode = System.Windows.Forms.AutoScaleMode.Font
        Me.ClientSize = New System.Drawing.Size(320, 240)
        Me.FormBorderStyle = Windows.Forms.FormBorderStyle.FixedSingle
        Me.MaximizeBox = False
        Me.Controls.Add(Me.picConway)
        Me.Name = "frmView"
        Me.Text = "Conway's Game of Life"
        CType(Me.picConway, System.ComponentModel.ISupportInitialize).EndInit()
        Me.ResumeLayout(False)

    End Sub
    Friend WithEvents picConway As System.Windows.Forms.PictureBox
#End Region
End Class