• (3 Pages)
  • +
  • 1
  • 2
  • 3

Basic Calculator in VB.Net Rate Topic: **--- 4 Votes

#1 PsychoCoder  Icon User is offline

  • Google.Sucks.Init(true);
  • member icon

Reputation: 1641
  • View blog
  • Posts: 19,853
  • Joined: 26-July 07

Post icon  Posted 09 September 2007 - 10:41 AM

In this tutoral, Basic Calculator in VB.Net, we will look at creating a basic calculator. The calculator will have the following functionality:
  • Addition
  • Subtraction
  • Division
  • Multiplication
  • Square Root
  • Exponents (Power Of)
  • Clear Entry
  • Clear All

There will be a 2nd tutorial that will cover some more advanced features such as
  • Adding a number to memory
  • Removing a number from memory
  • Calculating with a number in memory
  • Entering numbers by typing

The first thing you need to do is create a new project in Visual Studio (or Visual Basic Express Edition if thats what you use). Once you have created your new project you need to create your user interface, your user interface should look like this:

Attached Image

Your user interface will consist of
  • Buttons 0 through 9
  • Buttons for
    • Addition

    • Subtraction

    • Division

    • Multiplication

    • Exponents (x^)

    • Inverse (1/x)

    • Square Root (sqrt)

  • Decimal
  • Equals
  • Backspace
  • CE (Clear Entry)
  • C (Clear All)
  • ReadOnly TextBox for input (Make sure TabStop is also set to False)

How you setup your user interface is up to you, but remember people are used to a calculator looking a certain way so you may wish to follow my example.

In this tutorial I will show you how to code two of the number buttons (since all 10 are the same except the zero button), how to code the calculations buttons, the clear buttons and the backspace buttons. Before writing any code you need to add the following variables to the top (Globals):

'variables to hold operands
Private valHolder1 As Double
Private valHolder2 As Double
'Varible to hold temporary values
Private tmpValue As Double
'True if "." is use else false
Private hasDecimal As Boolean
Private inputStatus As Boolean
Private clearText As Boolean
'variable to hold Operater
Private calcFunc As String



These variables will be used through out our program thats why they're globals. Now, before any calculations can be done, the user needs to be able to enter numbers into the input box, so lets take a look at how to do that (Ill use the number 1 key and the zero key).

Number one key:

Private Sub cmd1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmd1.Click
	 'Check the inputStatus
	 If inputStatus Then 'Its True
		 'Append values to the value
		 'in the input box
		 txtInput.Text += cmd1.Text
	 Else	'Value is False
		 'Set the value to the value of the button
		 txtInput.Text = cmd1.Text
		 'Toggle inputStatus to True
		 inputStatus = True
	 End If
	End Sub



When a user clicks a number button (in this case the number one button) we check the status of the inputStatus flag. If its true then we know we can just append the next value to the end of whats currently in the input box, otherwise we just enter the number into the input box. All the remaining numbers follow this procedure, except the zero button, this one is slightly different as we don't want the user to be able to enter zero as the first number (this is covered more in the decimal button functionality).

So lets take a look at how we code the zero button:

Private Sub cmd0_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmd0.Click
	 'Check the input status
	 If inputStatus Then 'If true
		 'Now check to make sure our
		 'input box has a value
		 If txtInput.Text.Length >= 1 Then
			'Add our zero
			txtInput.Text += cmd0.Text
		 End If
	 End If
End Sub



First we check the status of the inputStatus flag, if its true we know we can enter a number in the box. Here we do a second check, we make sure the length of the text in the input box is at least 1 (it has a value), if so we enter the zero into the input box.

For adding a decimal to our input box we need to first make sure our input box doesn't already contain one, then we need to make sure our input box has a value (don't want the user to be able to enter a decimal as the first value). Then we make sure the value in the input area isn't 0 (zero), this we will handle later.

If all those are true then we enter the decimal then toggle the hasDecimal to True, so the user cant enter a 2nd one. Now, if the input area doesn't have a value, we enter 0., as we assume the user is wanting to work with a decimal value such as 0.5. Lets take a look at the procedure for doing this:

Private Sub cmdDecimal_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdDecimal.Click
		'Check for input status (we want true)
   If inputStatus Then
	   'Check if it already has a decimal (if it does then do nothing)
	   If Not hasDecimal Then
		   'Check to make sure the length is > than 1
		   'Dont want user to add decimal as first character
		   If txtInput.Text.Length > 1 Then
				'Make sure 0 isnt the first number
				If Not txtInput.Text = "0" Then
					'It met all our requirements so add the zero
					txtInput.Text += cmdDecimal.Text
					'Toggle the flag to true (only 1 decimal per calculation)
					hasDecimal = True
				End If
		  Else
			   'Since the length isnt > 1
			   'make the text 0.
			   txtInput.Text = "0."
		  End If
	   End If
   End If
End Sub



As you can see, we check all the items mentioned above, if they're True we add the decimal, otherwise we add 0. to the input area.

Next we want to be able to add numbers together. The first thing we do here is to make sure the input box has a value (Length > 1). If it does then we check the calcFunc value. The calcFunction variable will be used to tell our CalculateTotals procedure which calculation to perform. Here, if the value is empty (String.Empty) we assign the value of our input box to a variable, valHolder1, which will hold the first part of all calculations, then clear out the input box so the user can enter a 2nd number.

If the calcFunc variable isnt empty then we call our CalculateTotals procedure to display a total to the user. We then assign the value of Add to our variable for the next turn through, then we toggle the bb]hasDecimal[/b] flag to False.

Now lets take a look at how we accomplished this:

Private Sub cmdAdd_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdAdd.Click
   'Make sure out input box has a value
   If txtInput.Text.Length <> 0 Then
	   'Check the value of our function flag
	   If calcFunc = String.Empty Then 'Flag is empty
		   'Assign the value in our input
		   'box to our holder
		   valHolder1 = CType(txtInput.Text, Double)
		   'Empty the input box
		   txtInput.Text = String.Empty
	   Else 'Flag isnt empty
		   'Call our calculate totals method
		   CalculateTotals()
	   End If
	   'Assign a value to our calc function flag
	   calcFunc = "Add"
	   'Toggle the decimal flag
	   hasDecimal = False
   End If
End Sub



Believe it or not, all the other basic calculation buttons are the same as the Add button, with the exception of what we set calcFunc to. In the other buttons we set this variable to the calculation we want to perform, Subtract,
Divide, Multiply, and so on, so there really isn't a reason to show how that is done since we did the Add button and the others are the same.

Lets say you want to give the user the option to calculation Exponents, 4^2 for example. To code this button you need a couple of checks before doing anything. First we need to check and make sure the input area has a value, if it does then we check to see the value of the calcFunc variable.

If this is empty, we then convert the value of the input area to a Double and assign it to the valHolder1 variable to hold on to, this will be used for the calculations in the CalculateTotals procedure and empth the value from the input area.. If its not empty we directly call the CalculateTotals function as this means the user has already entered 2 numbers.

We then assign the value of PowerOf to our calcFunc variable, this will tell CalculateTotals what calculation to perform, and toggle the hasDecimal flag to False.

Lets take a look at how we accomplished all of this:

Private Sub cmdPowerOf_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdPowerOf.Click
   'Make sure the input box has a value
   If txtInput.Text.Length <> 0 Then
	   'Check if the calcFunc flag is empty
	   If calcFunc = String.Empty Then
		   'Assign the value of the input box to our variable
		   valHolder1 = CType(txtInput.Text, Double)
		   'Empty the input box
		   'So the user can enter the power of value
		   txtInput.Text = String.Empty
	   Else
		   'Call the calculate totals method
		   CalculateTotals()
	   End If
	   'Assign our flag the value of "PowerOf"
	   calcFunc = "PowerOf"
	   'Reset the decimal flag
	   hasDecimal = False
   End If
End Sub



Doing a Square Root is somewhat different as it doesn't take 2 values, just the number you want the square root of, so some of the checking required in the other calculations isn't required here. For a Square Root we first check to ensure the input area has a value. If it does have a value we assign the value of the input area, converted to a Double, to our tmpValue variable.

Once we have the value, we call the System.Math.Sqrt Method to perform the calculations on the tmpValue variable. Once this is complete we assign the resulting value to our input area, then toggle the hasDecimal flag to False.

Lets take a look at how this is done:

Private Sub cmdSqrRoot_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdSqrRoot.Click
   'Make sure the input box has a value
   If txtInput.Text.Length <> 0 Then
	   'Assign our variable the value in the input box
	   tmpValue = CType(txtInput.Text, Double)
	   'Perform the square root
	   tmpValue = System.Math.Sqrt(tmpValue)
	   'Display the results in the input box
	   txtInput.Text = CType(tmpValue, String)
	   'Clear the decimal flag
	   hasDecimal = False
   End If
End Sub



The Equals button is quite simple. Here, we first check to make sure our input area has a value and that our valHolder1 variable isn't a zero (Divide by 0 is a bad thing). If both of these are true we call the CalculateTotals procedure to perform our calculations based on the value of the calcFunc flag. We then clear the value of calcFunc and toggle the hasDecimal flag to False. This is done like this:

Private Sub cmdEqual_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdEqual.Click
   'Make sure theres a value in the input box
   'And that our temp value isnt 0
   If txtInput.Text.Length <> 0 AndAlso valHolder1 <> 0 Then
	   'Call the calculate totals method
	   CalculateTotals()
	   'Clear the calcFunction value
	   calcFunc = String.Empty
	   'Toggle the decimal flag
	   hasDecimal = False
   End If
End Sub



We have 3 more buttons to look at before we look at the CalculateTotals procedure. First we'll look at the backspace button.For the backspace, first we need to make sure the input are has a value. If it does then we retrieve the next to last character and see if its a decimal, if it is we toggle the hasDecimal flag to False. Next we create an Integer variable (loc) to hold the length of the contents in the input area. From there we use Remove, along with loc to remove the last character of the string for each time the user clicks the backspace button.

Private Sub cmdBackspace_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdBackspace.Click
   'Declare locals needed
   Dim str As String
   Dim loc As Integer
   'Make sure the text length is > 1
   If txtInput.Text.Length > 0 Then
	   'Get the next to last character
	   str = txtInput.Text.Chars(txtInput.Text.Length - 1)
	   'Check if its a decimal
	   If str = "." Then
		   'If it is toggle the hasDecimal flag
		   hasDecimal = False
	   End If
	   'Get the length of the string
	   loc = txtInput.Text.Length
	   'Remove the last character, incrementing by 1
	   txtInput.Text = txtInput.Text.Remove(loc - 1, 1)
   End If
End Sub



The last 2 buttons I'm going to demonstrate are the CE (Clear entry) and C (Clear all) buttons. These are very simple. First the clear entry button. What we do here is set the value in the input area to empty (String.Empty), and the hasDecimal flag to false.

Private Sub cmdClearEntry_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdClearEntry.Click
   'Empty the input box
	txtInput.Text = String.Empty
	'Toggle the decimal flag
	hasDecimal = False
End Sub



The clear all button required a bit more code as we do more with this button. Here we set our 2 holder variables, valHolder1 and valHolder2 to 0 (zero), we then set the calcFunc flag to String.Empty and the hasDecimal flag to False, like this:

Private Sub cmdClearAll_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdClearAll.Click
   'Empty the text in the input box
   txtInput.Text = String.Empty
   'Clear out both temp values
   valHolder1 = 0
   valHolder2 = 0
   'Set the calc switch to empty
   calcFunc = String.Empty
   'Toggle the hasDecimal flag
   hasDecimal = False
End Sub



Those are the buttons you need for a Basic calculator. The final thing we're going to look at is the procedure that actually does the calculations, CalculateTotals. Here the first thing we do is set our variable valHolder2 to the current value of the input area. We then do a Select Case on the value of calcFunc so we know which calculations to perform. We perform our calculations (add, subtract, divide, multiply, exponent, etc) and set the results to the input area so the user can see their results. Finally we set the inputEntry flag to False. THis iw hat this procedure looks like:

Private Sub CalculateTotals()
   valHolder2 = CType(txtInput.Text, Double)
   Select Case calcFunc
	   Case "Add"
		   valHolder1 = valHolder1 + valHolder2
	   Case "Subtract"
		   valHolder1 = valHolder1 - valHolder2
	   Case "Divide"
		   valHolder1 = valHolder1 / valHolder2
	   Case "Multiply"
		   valHolder1 = valHolder1 * valHolder2
	   Case "PowerOf"
		   valHolder1 = System.Math.Pow(valHolder1, valHolder2)
   End Select
   txtInput.Text = CType(valHolder1, String)
   inputStatus = False
End Sub



NOTE: For the Exponents (Power Of) we use the System.Math.Pow Method for calculating the value.

Thats it, thats how you create a basic calculator in VB.Net. I hope you find this tutorial helpful. I am including the project file with this tutorial, but remember this solution is under the GNU GENERAL PUBLIC LICENSE so you may not remove the header from the files or turn this project in as your homework assignment.

I know I am forced to go with the honor system in this, but if you do just turn this in as your assignment not only will you be cheating, but you will learn nothing, and subsequently wont know enough to become a programmer once you get out of school.

I will be doing a 2nd part to this tutorial where I look at adding more advanced functionality to this calculator, such
as adding a number to memory, removing a number from memory, calculations with a number in memory and more. Also, I will be creating a C# version of this calculator for the C# users.

Thank you for reading!

Attached File  PC_Calculator.zip (122.58K)
Number of downloads: 24162

Is This A Good Question/Topic? 3
  • +

Replies To: Basic Calculator in VB.Net

#2 Louisda16th  Icon User is offline

  • dream.in.assembly.code
  • member icon

Reputation: 15
  • View blog
  • Posts: 1,967
  • Joined: 03-August 06

Posted 13 September 2007 - 07:06 AM

Nice tutorial.

This post has been edited by Louisda16th: 13 September 2007 - 07:37 AM

Was This Post Helpful? 0
  • +
  • -

#3 PsychoCoder  Icon User is offline

  • Google.Sucks.Init(true);
  • member icon

Reputation: 1641
  • View blog
  • Posts: 19,853
  • Joined: 26-July 07

Posted 13 September 2007 - 07:28 AM

I made this tutorial to show people how to make one, instead of having to answer the question time and time and time again. Following a tutorial is no different than reading it in a book so I don't see your problem with it.

I know I could have used a control array of types, I have written code to do that very thing, but this is a beginner tutorial, and if someone needs help creating a calculator throwing a control array at them isn't going to do anything but confuse them. I want them to learn the basics before trying to jump into more advanced topics.

The Team of DIC didn't have a problem with me writing this tutorial, so why do you? :)

<edit>
It isn't considered good etiquette to post links like that in someone's tutorial. The whole purpose of a tutorial is to teach, not for someone to come in a hijack the tutorial with links to other topics
</edit>

This post has been edited by PsychoCoder: 13 September 2007 - 07:29 AM

Was This Post Helpful? 0
  • +
  • -

#4 Louisda16th  Icon User is offline

  • dream.in.assembly.code
  • member icon

Reputation: 15
  • View blog
  • Posts: 1,967
  • Joined: 03-August 06

Posted 13 September 2007 - 07:31 AM

Hey!! I didn't say I had anything against a tutorial. The later part of my post was for people who read your tut and want to simplify it. I remember making a calculator in VB6 using control arrays. It becomes a pain if you get used to the feature. I just wanted to tell how one could use the arrays to do the same job. The link was to show how to use arrays not how make a calculator. :)

Quote

But its better if it isn't a tutorial.

What I meant by that is, its better if a tut "Creating a Calculator Using Arrays of Controls" isn't written.
I'll go ahead and remove the link. The point of confusing someone does make sense however........ Sorry

This post has been edited by Louisda16th: 13 September 2007 - 07:47 AM

Was This Post Helpful? 0
  • +
  • -

#5 Smarf  Icon User is offline

  • D.I.C Head

Reputation: 6
  • View blog
  • Posts: 80
  • Joined: 21-September 07

Posted 26 October 2007 - 09:22 AM

Great tutorial, I'm looking forward to trying it out when I get home and in front of the IDE.

I did have a question though about the interface:

In your user interface for the calculator there are grey lines making up a border that seperates the buttons from the display area. I've been wanting to add these to programs of my own and have no idea what they're called. The only things we've used so far are textboxes, labels, listboxes and buttons but it always looks shoddy without those borders.

PS: Please don't tell me they're actually called borders and I somehow missed them in the Add object do-hickey.
Was This Post Helpful? 1
  • +
  • -

#6 PsychoCoder  Icon User is offline

  • Google.Sucks.Init(true);
  • member icon

Reputation: 1641
  • View blog
  • Posts: 19,853
  • Joined: 26-July 07

Posted 26 October 2007 - 10:03 AM

Smarf,

In your toolbox, under containers (I believe thats the name of the group) is a control called GroupBox, thats the control you want :)
Was This Post Helpful? 1
  • +
  • -

#7 Cpt.Franco  Icon User is offline

  • New D.I.C Head

Reputation: 0
  • View blog
  • Posts: 1
  • Joined: 08-December 07

Posted 08 December 2007 - 10:10 PM

Hey I am a real beigner at VB and its the first tutorial a take here and well it helped me alot. I was even able to creat my own code for the +/- button. :) thanks alot

here is my very first code i created on my owne hope its actually good.

  Private Sub PlusMinus_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles PlusMinus.Click

		If inputStatus Then
			If txtInput.Text = -txtInput.Text Then
				txtInput.Text = +txtInput.Text
			ElseIf txtInput.Text = +txtInput.Text Then
				txtInput.Text = -txtInput.Text
			End If
		End If

	End Sub 

Was This Post Helpful? 0
  • +
  • -

#8 j0e  Icon User is offline

  • New D.I.C Head

Reputation: 1
  • View blog
  • Posts: 46
  • Joined: 01-June 08

Posted 01 June 2008 - 04:14 AM

Hi, i downloaded and test your work, very good piece of work but i found a Bug on it. It is located in Decimal Button. What i did was :
100.1 + 1 and the result it gave me was 1002.
More over when i click a 1 and then the Decimal button it gives a 0. than 1.
In other words it doesnt recognise the decimal string "." I think that a "," would give a solution to the code but need some additional changes. Working on that and sorry for my English.

This post has been edited by j0e: 01 June 2008 - 04:19 AM

Was This Post Helpful? 1
  • +
  • -

#9 RMEdi  Icon User is offline

  • New D.I.C Head

Reputation: 0
  • View blog
  • Posts: 4
  • Joined: 23-June 08

Posted 23 June 2008 - 09:24 AM

Private Sub cmd1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmd1.Click
'Check the inputStatus
If inputStatus Then 'Its True
'Append values to the value
'in the input box
txtInput.Text += cmd1.Text
Else 'Value is False
'Set the value to the value of the button
txtInput.Text = cmd1.Text
'Toggle inputStatus to True
inputStatus = True
End If
End Sub

I am a real beginner to VB.Net, I still don't understand how this command can create an input of "1" to the text box, and if I change it to cmd2, it will give a "2", etc. Please explain it to me if you have time. Thank you very much.
Was This Post Helpful? 0
  • +
  • -

#10 PsychoCoder  Icon User is offline

  • Google.Sucks.Init(true);
  • member icon

Reputation: 1641
  • View blog
  • Posts: 19,853
  • Joined: 26-July 07

Posted 23 June 2008 - 10:13 AM

What it is doing is adding the value of the Text Property of the command button to the TextBox. Look at cmd1, it has a text property of 1, so 1 is added, cmd2 has a text property of 2, and so on
Was This Post Helpful? 1
  • +
  • -

#11 _HAWK_  Icon User is offline

  • Master(Of Foo)
  • member icon

Reputation: 1055
  • View blog
  • Posts: 4,087
  • Joined: 02-July 08

Posted 02 July 2008 - 01:43 PM

View Postj0e, on 1 Jun, 2008 - 04:14 AM, said:

Hi, i downloaded and test your work, very good piece of work but i found a Bug on it. It is located in Decimal Button. What i did was :
100.1 + 1 and the result it gave me was 1002.
More over when i click a 1 and then the Decimal button it gives a 0. than 1.
In other words it doesnt recognise the decimal string "." I think that a "," would give a solution to the code but need some additional changes. Working on that and sorry for my English.

Hi there Joe, the fix is simple, change the line of code for the decimal button,
from:If txtInput.Text.Length > 1 Then
to :If txtInput.Text.Length > 0 Then

it should work fine.

This post has been edited by hawkvalley1: 02 July 2008 - 01:45 PM

Was This Post Helpful? 1
  • +
  • -

#12 areyouon  Icon User is offline

  • New D.I.C Head

Reputation: 0
  • View blog
  • Posts: 3
  • Joined: 25-July 08

Posted 25 July 2008 - 04:05 PM

Private Sub btnAdd_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAdd.Click

'Verify input box has value entered
If Me.txtDisplay.Text.Length <> 0 Then 'check flag valu
If calcFunc = String.Empty Then 'flag is empty
valHolder1 = CType(Me.txtDisplay.Text, Double) 'Assign value to var
Me.txtDisplay.Text = String.Empty 'Clear input box
Else
CalculateTotals()
End If

calcFunc = "ADD"
hasDecimal = False
End If

End Sub
End Class

Was going great but my VB 08 Express isn't recognizing the "CalculateTotals" procedure. What am I not getting here? Any help is greatly appreciated.
Was This Post Helpful? 0
  • +
  • -

#13 PsychoCoder  Icon User is offline

  • Google.Sucks.Init(true);
  • member icon

Reputation: 1641
  • View blog
  • Posts: 19,853
  • Joined: 26-July 07

Posted 25 July 2008 - 04:11 PM

You did use the CalculateTotals method included in the tutorial correct?

Private Sub CalculateTotals()
   valHolder2 = CType(txtInput.Text, Double)
   Select Case calcFunc
       Case "Add"
           valHolder1 = valHolder1 + valHolder2
       Case "Subtract"
           valHolder1 = valHolder1 - valHolder2
       Case "Divide"
           valHolder1 = valHolder1 / valHolder2
       Case "Multiply"
           valHolder1 = valHolder1 * valHolder2
       Case "PowerOf"
           valHolder1 = System.Math.Pow(valHolder1, valHolder2)
   End Select
   txtInput.Text = CType(valHolder1, String)
   inputStatus = False
End Sub


Was This Post Helpful? 0
  • +
  • -

#14 areyouon  Icon User is offline

  • New D.I.C Head

Reputation: 0
  • View blog
  • Posts: 3
  • Joined: 25-July 08

Posted 26 July 2008 - 11:06 AM

I should've finished the tutorial before getting frustrated. I hadn't reached that part yet. I should know better than to try writing code after 5pm!!! Brain doesn't work as well.

I'm still having an issue with the "0" and "0." portion but I'll wait until all is finished before seeing if I need any further help.

Thanks for the reply!!!


View PostPsychoCoder, on 25 Jul, 2008 - 04:11 PM, said:

You did use the CalculateTotals method included in the tutorial correct?

Private Sub CalculateTotals()
   valHolder2 = CType(txtInput.Text, Double)
   Select Case calcFunc
       Case "Add"
           valHolder1 = valHolder1 + valHolder2
       Case "Subtract"
           valHolder1 = valHolder1 - valHolder2
       Case "Divide"
           valHolder1 = valHolder1 / valHolder2
       Case "Multiply"
           valHolder1 = valHolder1 * valHolder2
       Case "PowerOf"
           valHolder1 = System.Math.Pow(valHolder1, valHolder2)
   End Select
   txtInput.Text = CType(valHolder1, String)
   inputStatus = False
End Sub


Was This Post Helpful? 0
  • +
  • -

#15 areyouon  Icon User is offline

  • New D.I.C Head

Reputation: 0
  • View blog
  • Posts: 3
  • Joined: 25-July 08

Posted 26 July 2008 - 01:09 PM

I'm still having an issue with the decimal button. Upon load it won't show (or acknowledge) "0." but will work if I enter any other number first and then press decimal. If I then hit Clear or CE I can then press decimal and "0." appears as first character. I thought maybe upon load something was telling the application "hasDecimal=True" but can't find any indication of that. Besides, if that were happening I couldn't add a decimal after entering a number.

I've rechecked my code but can't find any errors either. Any ideas?

Other than this, all works fine... Great tutorial!

Here's my decimal btn code for reference:

Private Sub btnDecimal_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnDecimal.Click

		'Check input status and limit to one decimal with "0" first
		If inputStatus Then
			If Not hasDecimal Then
				If Me.txtDisplay.Text.Length > 0 Then
					If Not Me.txtDisplay.Text = "0" Then
						Me.txtDisplay.Text += Me.btnDecimal.Text
						hasDecimal = True					   'Turns decimal limiter on
					End If
				Else
					'since length not > 1 make text "0."
					Me.txtDisplay.Text = "0."
				End If
			End If
		End If

	End Sub





View Postareyouon, on 26 Jul, 2008 - 11:06 AM, said:

I should've finished the tutorial before getting frustrated. I hadn't reached that part yet. I should know better than to try writing code after 5pm!!! Brain doesn't work as well.

I'm still having an issue with the "0" and "0." portion but I'll wait until all is finished before seeing if I need any further help.

Thanks for the reply!!!


View PostPsychoCoder, on 25 Jul, 2008 - 04:11 PM, said:

You did use the CalculateTotals method included in the tutorial correct?

Private Sub CalculateTotals()
   valHolder2 = CType(txtInput.Text, Double)
   Select Case calcFunc
       Case "Add"
           valHolder1 = valHolder1 + valHolder2
       Case "Subtract"
           valHolder1 = valHolder1 - valHolder2
       Case "Divide"
           valHolder1 = valHolder1 / valHolder2
       Case "Multiply"
           valHolder1 = valHolder1 * valHolder2
       Case "PowerOf"
           valHolder1 = System.Math.Pow(valHolder1, valHolder2)
   End Select
   txtInput.Text = CType(valHolder1, String)
   inputStatus = False
End Sub


Was This Post Helpful? 0
  • +
  • -

  • (3 Pages)
  • +
  • 1
  • 2
  • 3