[Athinar]

Error Code
Run-Time error 438
Object doesn't support this property or method

.Index = curr_obj.TabIndex

Do we need to add a "Reference"?

Do we need to add the name of the form (i.e. frmRemedy)

added a MsgBox curr_obj

in

Public Sub GetLocation(frmRemedy As Form)

For Each curr_obj In frmRemedy
'Resize the Array by 1, and preserve
'the original objects in the array
ReDim Preserve List(i)
With List(i)
.Name = curr_obj
MsgBox curr_obj & " i " & i

I'm getting "False i 0"

VB6 does have a TabIndex of "0"

What in the programming decides which object in the form is number i = 0, curr_obj?

My program starts with
curr_obj = TabIndex 55, when i= 0, why, I'm looking for the reason why it starts there

TabIndex ends with 238

Ends with i = 222, then Run Time Error 438

Why not start with TabIndex = 0 and count up from there and end it with a IF statement?

What about any "Lines" that are in the Form?

I think it might be the Lines in the Form that is causing the the runtime error, no TabIndex

Yes, removed the "Lines" and it went further, but now error for the Fonts.

lblInstructions.Font = SetFontSize()

has a Run-time error 424
Object Required

I see

lblInstructions.Font = SetFontSize()
and
lblInstructions.FontSize = SetFontSize()

This post has been edited by Athinar: 27 June 2008 - 04:06 AM

[karthik622]

[quote name='PsychoCoder' date='6 Oct, 2007 - 03:14 PM' post='264127']
Welcome to this tutorial on resizing a form based on screen size in Visual
Hi this seems not working for me if the form contains the image list control please help me in this

[cyber_sam]

i m getting error downloading form control .whats the problem

[tylrwb]

Having a little trouble with this. I cannot compile my project because it does not like this line:
lblInstructions.Font = SetFontSize()

It did not like the line:
CenterForm Me

neither one of these are refernced in the code other then SetFontSize() it doesn't like lblInstructions.font
What am i supposed to do with that?

I have about 15 forms that i put this in:

Private Sub Form_Load()
GetLocation Me
CenterForm Me
ResizeForm Me

lblInstructions.Font = SetFontSize()
End Sub

Private Sub Form_Resize()
ResizeControls Me
lblInstructions.FontSize = SetFontSize()
End Sub

of course some of the Form_load has other stuff in it.
The rest is in a module called FormControl (formControl).bas

thanks

[DocType]

Cowman, on 16 Mar, 2008 - 05:10 PM, said:

VB6 must be a lot different than VB 2008 Express...
Although your code wouldn't work for me it did send
me in the right direction. Thanks Here is how I reworked
it for VB express. Hope this helps some one.

[Public Sub ResizeControls()
REM By Cowman thanks to Richard L. McCutchen's sample
REM for Visual Basic Express 2005/2008 to fit large forms to smaller screen res.
REM should be easy enough to make smaller forms fill screen as well with a little work.
REM Paste into application and put 'ResizeControls()' at begining of formload.
Dim contrls As Object
Dim ratioW, ratioH, ratio As Double
Dim screenW, screenH, fhight, fwidth, z As Integer
Dim Fsz As Single
ratio = 0 : ratioH = 0 : ratioW = 0
REM Get Current screen res.
screenW = CInt(My.Computer.Screen.WorkingArea.Width)
screenH = CInt(My.Computer.Screen.WorkingArea.Height)
REM get form size
fhight = Me.Height
fwidth = Me.Width

If fhight > screenH Then ratioH = CInt((screenH / fhight) * 100) REM to 2 decimal points
If fwidth > screenW Then ratioW = CInt((screenW / fwidth) * 100)
REM chose the smaller of either width or height ratio to ensure fit
If ratioH > ratioW Then
ratio = ratioW / 100
Else : ratio = ratioH / 100
End If
If ratio = 0 Then Exit Sub REM form is smaller than screen- -exit
Me.Width = screenW REM maxized to working area-- developer can choose to make smaller with more code here
Me.Height = screenH
Me.CenterToParent()
formitems = Me.Controls.Count - 1
contrls = Me.Controls
REM resize all the forms items
For z = 0 To formitems
Me.Controls.Item(z).Width = CInt((Me.Controls.Item(z).Width) * ratio)
Me.Controls.Item(z).Height = CInt((Me.Controls.Item(z).Height) * ratio)
Me.Controls.Item(z).Left = CInt((Me.Controls.Item(z).Left) * ratio)
Me.Controls.Item(z).Top = CInt((Me.Controls.Item(z).Top) * ratio)
Fsz = CSng(Me.Controls.Item(z).Font.Size)
Fsz = CSng((CInt((Fsz * ratio) * 10) / 10)) REM font must be single using 1 decimal point
Dim f As New System.Drawing.Font("Arial", Fsz)
' Assign the font to the control
Me.Controls.Item(z).Font = f
Next z
End Sub]

I tried this in Visual Basic 2008 Express

I had to declare a variable "formitems" wasn't declared.

The code ran without any errors, but there was no effect.

This post has been edited by DocType: 23 February 2009 - 09:07 PM

[PsychoCoder]

@DocType That's because this code is for Visual Basic 6, not VB.NET

[DocType]

PsychoCoder, on 23 Feb, 2009 - 08:11 PM, said:

@DocType That's because this code is for Visual Basic 6, not VB.NET

Then why does it say this?

REM for Visual Basic Express 2005/2008 to fit large forms to smaller screen res.

[tylrwb]

Hey PsychoCoder - could you take a stab at my question i am kinda stuck here. The topic is above a bit. I am looking for the answers to where the refernce is for the font resize!

[PsychoCoder]

DocType, on 23 Feb, 2009 - 07:41 PM, said:

Then why does it say this?

REM for Visual Basic Express 2005/2008 to fit large forms to smaller screen res.

If you look at that line it's in someone's comment who converted this for VB.NET. This tutorial if for VB6 (as it says in the title and in the tutorial itself )

[cyber_sam]

I ve used this tutorial n this is workin fine
but when i added image control it was giving error invalid object , i ve solved
this problem by using

if not typeof obj is object 

n it is workin fine

but when i added the menu control it is giving error, pls tel me how to solve this problem. is there any alternative way?

This post has been edited by cyber_sam: 26 March 2009 - 10:43 PM

[vegitz]

Hi Sam,
I have my own resizing codes and I think it could help you on your problem; actually it's a generic approach so you can apply it on the tutorial here or on any solution:

Here is the code:

Private Sub Form_Resize()
Dim objControl As Control

If Me.WindowState = vbMinimized Then
' we have to check this. if not, your program will crash when minimized
Exit Sub
End If

' iterate through all the controls on the form to determine
' which to resize and which not to

' OPTION 1: determine via the type of control
For Each objControl In Me.Controls
If TypeOf objControl Is Menu Then
' ignore menu controls
Else
' do the resize here of other controls
End If
Next

' OPTION 2: determine via the "tag" property
' you can set the TAG during design via the properties window
' or programatically by setting it (ex. Text1.Tag="resize_me")
' the TAG value can be anything you like of course
For Each objControl In Me.Controls
If LCase(objControl.Tag) = LCase("resize_me") Then
' resize this
Else
' dont resize
End If
Next
End Sub


End of code:

Hope this helps you and the others.

cyber_sam, on 26 Mar, 2009 - 09:41 PM, said:

I ve used this tutorial n this is workin fine
but when i added image control it was giving error invalid object , i ve solved
this problem by using

if not typeof obj is object 

n it is workin fine

but when i added the menu control it is giving error, pls tel me how to solve this problem. is there any alternative way?

[paperclipmuffin]

Ho. Ly. Crap. That's long.

Well done!

[MistralRider]

PsychoCoder, on 6 Oct, 2007 - 03:14 PM, said:

Welcome to this tutorial on resizing a form based on screen size in Visual Basic 6. In this tutorial I will discuss a couple issues:

• Resize a form based on screen size
  
• Resize the controls on the form based on the form size
  
• Resize the font size of all controls based on the above 2 items

I have received this question for many years, and in my time in </dream.in.code> I have also been asked this question several times, so I thought it would be a good idea to write a tutorial based on this question. THought there are many commercial products out there that will accomplish this, how many students and everyday Joe's actually have the money to be buying these solutions? Not many I can assure you, so after getting this question numerous time, I decided it was time to write my own solution to this problem, and give it back to the programming community.

The code I'm about to show you I have in a Code Module, names FormControl that I include in all VB6 projects I create. This comes in real handy because as developers we don't know what screen resolution a client, or anyone else using our software, will be using. The first thing I have in my module is some Global variables that will be used through out the module, so I, of course, make them Global and accessible to the entire module. Here are the Globals you need to add to your Code Module:

Private List() As Control
Private curr_obj As Object
Private iHeight As Integer
Private iWidth As Integer
Private x_size As Double
Private y_size As Double

As you will see, the Globals are Private, I don't want them to be accessed from outside this Code Module. The first Global is an Array or type Control. This is a private Type I have created to hold all the properties of the controls on the form. Creating your own user defined type saves a lot of headaches down the road, and allows for resizing all controls in a single loop, referencing your type:

Private Type Control
	Index As Integer
	Name As String
	Left As Integer
	Top As Integer
	width As Integer
	height As Integer
End Type

As you can see, this Type holds all the information needed about a control: Index, Name, Left, Top, Width and Height, these items will come in use later, when we write the procedure to resize all the controls at once. Now lets talk about resizing a form based on the current screen resolution we will be referencing the Screen Object available to us in Visual Basic 6.

The 2 properties we're concerned with are Width and Height. These properties of the Screen Object give us access to the screen size available to us. So, to set the Forms size in relationship to the Screen size, we will be accessing the properties of the Form Object, mainly the width and height properties. In my Module I set the forms size to the screen's size divided by 2, you may want to test and find your own resolution. Here's the simple procedure for resizing your form in relationship to the available screen resolution:

Public Sub ResizeForm(frm As Form)
	'Set the forms height
	frm.height = Screen.height / 2
	'Set the forms width
	frm.width = Screen.width / 2
	'Resize all of the controls
	'based on the forms new size
	ResizeControls frm
End Sub

Simple isn't it, we change the forms size based on the screen size, then we reference a procedure called ResizeControls, we do this because resizing the form alone isn't what we're after. Well doing only this will cause some pretty ugly user interfaces, simply because you may be resizing your form, but the controls are staying the same size, which isn't a good thing.

So, you can either write a really long and ugly procedure to resize each control individually,not very maintainable, especially if you rename or add controls, or you can write a nice neat little procedure, based on a user defined type, which we have in our Code Module, and loop through them like this:

Public Sub ResizeControls(frm As Form)
Dim i As Integer
'   Get ratio of initial form size to current form size
x_size = frm.height / iHeight
y_size = frm.width / iWidth

'Loop though all the objects on the form
'Based on the upper bound of the # of controls
For i = 0 To UBound(List)
	'Grad each control individually
	For Each curr_obj In frm
		'Check to make sure its the right control
		If curr_obj.TabIndex = List(i).Index Then
			'Then resize the control
			 With curr_obj
				.Left = List(i).Left * y_size
				.width = List(i).width * y_size
				.height = List(i).height * x_size
				.Top = List(i).Top * x_size
			 End With
		End If
	'Get the next control
	Next curr_obj
Next i
End Sub

Here we use the UBound Function To get the highest index on the form, which gives us the last control's index. We then loop through all the controls, stopping at the highest index, and change the size of the control. Before this procedure can actually work, we need to know the current location of each control, well I have a solution for that as well.

In this Module is a method called GetLocation. What this method does is it logs the current position of each control, looping through all the controls located in our List() Array, which is populated with the controls on the form. On each iteration of the loop, we use the ReDim Statement and the Preserve keyword to increment the size of the array by 1 and preserve the objects already in the array. The code for that method is as follows:

Public Sub GetLocation(frm As Form)
Dim i As Integer
'   Load the current positions of each object into a user defined type array.
'   This information will be used to rescale them in the Resize function.

'Loop through each control
For Each curr_obj In frm
'Resize the Array by 1, and preserve
'the original objects in the array
	ReDim Preserve List(i)
	With List(i)
		.Name = curr_obj
		.Index = curr_obj.TabIndex
		.Left = curr_obj.Left
		.Top = curr_obj.Top
		.width = curr_obj.width
		.height = curr_obj.height
	End With
	i = i + 1
Next curr_obj
	
'   This is what the object sizes will be compared to on rescaling.
	iHeight = frm.height
	iWidth = frm.width
End Sub

Our Code Module is almost complete, there is but one thing we need to think about resizing, and that is the font size used in the application. Resizing, say a Label, and not resizing the font being used on the label will make for an ugly User Interface as well. So what we do is, we get the value of x_size, which is one of our Globals, and set in the ResizeControls method, we multiply that by 8 and that gives the font size I'm looking for, you needs may vary. Here is the code for resizing the font size:

Public Function SetFontSize() As Integer
	'Make sure x_size is greater than 0
	If Int(x_size) > 0 Then
	'Set the font size
		SetFontSize = Int(x_size * 8)
	End If
End Function

That's all the code you need for your form and control resizing based on the users screen resolution. It's all a matter of getting the mathematics right, then resetting the size of everything on the form to fit nicely in the current screen.

Now for how to use it, in the Form_Load Event you add a call to:

• GetLocation
  
• ResizeForm

And set the FontSize property of your controls, like this:

Private Sub Form_Load()
	GetLocation Me
	CenterForm Me
	ResizeForm Me
	
	lblInstructions.Font = SetFontSize()
End Sub

This Code Module also offers another feature. If someone were the resize your form while havin the application running, if you put a call to ResizeControls in the Form_Resize Event, this will take care of resizing everthing:

Private Sub Form_Resize()
	 ResizeControls Me
	 lblInstructions.FontSize = SetFontSize()
End Sub

I am providing the Code Module this code is in, this Module and code is under the GNU General Public License, so you can use, modify or distribute as you see fit, but the license header must stay intact. I hope you have found this tutorial informative and useful. For all your Visual Basic 6 Reference Needs go to the Visual Basic 6.0 Resource Center. Thank you for reading.

Happy Coding
attachment

I cannot unzip the file FormContro.zip, any suggestions?

[firebolt]

Make sure you are using VB6, not VB.NET

[MistralRider]

firebolt, on 1 Aug, 2009 - 05:54 PM, said:

Make sure you are using VB6, not VB.NET

I am using vb6 but when I try and unzip the file "FormControl.zip" I get a message saying that it is not a zip type file.